***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Aug 27, 2021                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BZT52-C33-AU A K 
.param
+vc0 = 1.346e-10		vc1 = 2.086e-11		vc2 = 1.000			vc3 = 3.083e-13		vc4 = 2.027e-1
+tc1 = 1.901e-2		tc2 = 9.101e-3		tc3 = 5.221e-3		tc4 = 5.701e-3
.func irexp(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*exp(vc4*v))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irexp(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1
***** dc model parameter *****
+ is = 8.084e-15		   n = 1.103		  rs = 5.457e-1
+ibv = 5.0e-3		 nbv = 1.0			  bv = 33
+ikf = 1.003e-2
***** capacitance parameter *****
+cjo = 1.510e-11		   m = 3.786e-1		  vj = 7.118e-1 
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25			  eg = 1.112		 xti = 3
+trs1 = 1.007e-5		trs2 = 1.885e-7		tikf = 1.0e-2
+tbv1 = 8.960e-4		tbv2 = -5.428e-7	
.ends BZT52-C33-AU
*$
